
cmake_minimum_required(VERSION 3.10)

project(chiaki)

# Like option(), but the value can also be AUTO
macro(tri_option name desc default)
    set("${name}" "${default}" CACHE STRING "${desc}")
    set_property(CACHE "${name}" PROPERTY STRINGS AUTO ON OFF)
endmacro()

option(CHIAKI_ENABLE_TESTS "Enable tests for Chiaki" ON)
option(CHIAKI_ENABLE_CLI "Enable CLI for Chiaki" ON)
option(CHIAKI_ENABLE_GUI "Enable Qt GUI" ON)
option(CHIAKI_ENABLE_ANDROID "Enable Android (Use only as part of the Gradle Project)" OFF)
option(CHIAKI_ENABLE_BOREALIS "Enable Borealis GUI (For Nintendo Switch or PC)" OFF)
tri_option(CHIAKI_ENABLE_SETSU "Enable libsetsu for touchpad input from controller" AUTO)
tri_option(CHIAKI_ENABLE_STEAMDECK_NATIVE "Enable sdeck for native gyro and haptic feedback from Steam Deck" ON)
option(CHIAKI_LIB_ENABLE_OPUS "Use Opus as part of Chiaki Lib" ON)
tri_option(CHIAKI_ENABLE_SPEEX "Use speex for echo cancelling mic playback" AUTO)
tri_option(CHIAKI_ENABLE_RUDP "Enable Remote Play over Internet" AUTO)
if(CHIAKI_ENABLE_GUI OR CHIAKI_ENABLE_BOREALIS)
	set(CHIAKI_FFMPEG_DEFAULT ON)
else()
	set(CHIAKI_FFMPEG_DEFAULT AUTO)
endif()
tri_option(CHIAKI_ENABLE_FFMPEG_DECODER "Enable FFMPEG video decoder" ${CHIAKI_FFMPEG_DEFAULT})
tri_option(CHIAKI_ENABLE_PI_DECODER "Enable Raspberry Pi-specific video decoder (requires libraspberrypi0 and libraspberrypi-doc)" AUTO)
option(CHIAKI_LIB_ENABLE_MBEDTLS "Use mbedtls instead of OpenSSL as part of Chiaki Lib" OFF)
option(CHIAKI_LIB_MBEDTLS_EXTERNAL_PROJECT "Fetch Mbed TLS instead of using system-provided libs" OFF)
option(CHIAKI_LIB_OPENSSL_EXTERNAL_PROJECT "Use OpenSSL as CMake external project" OFF)
option(CHIAKI_GUI_ENABLE_SDL_GAMECONTROLLER "Use SDL Gamecontroller for Input" ON)
option(CHIAKI_CLI_ARGP_STANDALONE "Search for standalone argp lib for CLI" OFF)
option(CHIAKI_ENABLE_STEAM_SHORTCUT "Add ability to create Steam shortcut" ON)
tri_option(CHIAKI_USE_SYSTEM_JERASURE "Use system-provided jerasure instead of submodule" AUTO)
tri_option(CHIAKI_USE_SYSTEM_NANOPB "Use system-provided nanopb instead of submodule" AUTO)
tri_option(CHIAKI_USE_SYSTEM_CURL "Use system-provided curl instead of submodule. Has to be built with experimental WebSocket support!" OFF)
option(CHIAKI_LIB_JSONC_EXTERNAL_PROJECT "Build json-c from source via FetchContent" OFF)
option(CHIAKI_LIB_MINIUPNPC_EXTERNAL_PROJECT "Build miniupnpc from source via FetchContent" OFF)
option(CLOUD_LAUNCHER_SPLIT_POC_TOOLS "Build Cloud Launcher split-session PoC tools" OFF)
option(CLOUD_LAUNCHER_PRODUCTION_PLAYER "Build the restricted Cloud Launcher split-session player" OFF)
option(CLOUD_LAUNCHER_INTERNAL_CLIENT_LIVENESS_TEST_HOOK
	"Build the internal-only named-event client liveness pause hook" OFF)

if(CLOUD_LAUNCHER_INTERNAL_CLIENT_LIVENESS_TEST_HOOK
		AND (NOT WIN32 OR NOT CLOUD_LAUNCHER_PRODUCTION_PLAYER))
	message(FATAL_ERROR
		"CLOUD_LAUNCHER_INTERNAL_CLIENT_LIVENESS_TEST_HOOK requires the Windows Cloud Launcher player")
endif()

set(CHIAKI_VERSION_MAJOR 1)
set(CHIAKI_VERSION_MINOR 10)
set(CHIAKI_VERSION_PATCH 0)
set(CHIAKI_VERSION ${CHIAKI_VERSION_MAJOR}.${CHIAKI_VERSION_MINOR}.${CHIAKI_VERSION_PATCH})

set(CPACK_PACKAGE_NAME "chiaki-ng")
set(CPACK_PACKAGE_DESCRIPTION "Open Source PlayStation Remote Play client for Linux, Mac, and Windows")
set(CPACK_PACKAGE_VERSION_MAJOR ${CHIAKI_VERSION_MAJOR})
set(CPACK_PACKAGE_VERSION_MINOR ${CHIAKI_VERSION_MINOR})
set(CPACK_PACKAGE_VERSION_PATCH ${CHIAKI_VERSION_PATCH})
set(CPACK_DEBIAN_PACKAGE_SHLIBDEPS ON)
set(CPACK_DEBIAN_PACKAGE_DESCRIPTION ${CPACK_PACKAGE_DESCRIPTION})
set(CPACK_DEBIAN_PACKAGE_SECTION "games")
include(CPack)

set(CHIAKI_IS_SWITCH ${NSWITCH})

if(APPLE)
	if(CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL "arm64")
		set(CMAKE_OSX_DEPLOYMENT_TARGET 13.0 CACHE STRING "Minimum OS X deployment version" FORCE)
	else()
		set(CMAKE_OSX_DEPLOYMENT_TARGET 12.0 CACHE STRING "Minimum OS X deployment version" FORCE)
	endif()
endif()

list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake;${CMAKE_CURRENT_SOURCE_DIR}/setsu/cmake")
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake;${CMAKE_CURRENT_SOURCE_DIR}/steamdeck_native/cmake")
set(CMAKE_CXX_STANDARD 11)

if(CHIAKI_IS_SWITCH)
	# force mbedtls as crypto lib
	set(CHIAKI_LIB_ENABLE_MBEDTLS ON)
	add_definitions(-D__SWITCH__)
endif()

if(CHIAKI_USE_SYSTEM_JERASURE)
	if(CHIAKI_USE_SYSTEM_JERASURE STREQUAL AUTO)
		find_package(Jerasure QUIET)
		set(CHIAKI_USE_SYSTEM_JERASURE ${Jerasure_FOUND})
	else()
		find_package(Jerasure REQUIRED)
		set(CHIAKI_USE_SYSTEM_JERASURE ON)
	endif()
endif()

if(CHIAKI_ENABLE_GUI)
	find_package(PkgConfig REQUIRED)
	pkg_check_modules(LIBPLACEBO REQUIRED libplacebo>=7.349.0 IMPORTED_TARGET)
endif()

if(CHIAKI_USE_SYSTEM_CURL)
	if (CHIAKI_USE_SYSTEM_CURL STREQUAL AUTO)
		find_package(CURL COMPONENTS HTTP HTTPS WS WSS QUIET)
		set(CHIAKI_USE_SYSTEM_CURL ${CURL_FOUND})
	else()
		find_package(CURL REQUIRED COMPONENTS HTTP HTTPS WS WSS)
		set(CHIAKI_USE_SYSTEM_CURL ON)
	endif()
endif()

if(CHIAKI_ENABLE_SPEEX)
	set(SpeexDSP_FOUND FALSE)
	find_package(SpeexDSP QUIET)
	pkg_check_modules(SpeexDSP speexdsp IMPORTED_TARGET)
	if(SpeexDSP_FOUND)
		set(CHIAKI_ENABLE_SPEEX ON)
		message(STATUS "Speex DSP found echo cancelling and noise suppression enabled")
	else()
		set(CHIAKI_ENABLE_SPEEX OFF)
		message(STATUS "Speex DSP not found echo cancelling and noise suppression disabled")
	endif()
endif()

find_package(PythonInterp 3 REQUIRED) # Make sure nanopb doesn't find Python 2.7 because Python 2 should just die.

if(CHIAKI_USE_SYSTEM_NANOPB)
	if(CHIAKI_USE_SYSTEM_NANOPB STREQUAL AUTO)
		find_package(Nanopb QUIET)
		set(CHIAKI_USE_SYSTEM_NANOPB ${Nanopb_FOUND})
	else()
		find_package(Nanopb REQUIRED)
		set(CHIAKI_USE_SYSTEM_NANOPB ON)
	endif()
endif()

if(CHIAKI_LIB_OPENSSL_EXTERNAL_PROJECT)
	include(OpenSSLExternalProject)
endif()

add_subdirectory(third-party)

add_definitions(-DCHIAKI_VERSION_MAJOR=${CHIAKI_VERSION_MAJOR} -DCHIAKI_VERSION_MINOR=${CHIAKI_VERSION_MINOR} -DCHIAKI_VERSION_PATCH=${CHIAKI_VERSION_PATCH} -DCHIAKI_VERSION=\"${CHIAKI_VERSION}\")

if(CHIAKI_LIB_ENABLE_MBEDTLS)
	add_definitions(-DCHIAKI_LIB_ENABLE_MBEDTLS)
	if(CHIAKI_LIB_MBEDTLS_EXTERNAL_PROJECT)
		set(FETCHCONTENT_QUIET CACHE BOOL FALSE)
		include(FetchContent)
		set(ENABLE_TESTING CACHE INTERNAL OFF)
		set(ENABLE_PROGRAMS CACHE INTERNAL OFF)
		set(USE_SHARED_MBEDTLS_LIBRARY CACHE INTERNAL OFF)
		FetchContent_Declare(
			mbedtls
			GIT_REPOSITORY https://github.com/Mbed-TLS/mbedtls.git
			GIT_TAG 8b3f26a5ac38d4fdccbc5c5366229f3e01dafcc0 # v2.28.0
			GIT_PROGRESS TRUE
		)
		FetchContent_MakeAvailable(mbedtls)
	endif()
endif()

if(CHIAKI_ENABLE_STEAM_SHORTCUT)
	message(STATUS "Steam shortcut enabled")
else()
	message(STATUS "Steam shortcut disabled")
endif()

if(CHIAKI_ENABLE_FFMPEG_DECODER)
	find_package(FFMPEG COMPONENTS avcodec avutil avformat)
	if(FFMPEG_FOUND)
		set(CHIAKI_ENABLE_FFMPEG_DECODER ON)
	else()
		if(NOT CHIAKI_ENABLE_FFMPEG_DECODER STREQUAL AUTO)
			message(FATAL_ERROR "CHIAKI_ENABLE_FFMPEG_DECODER is set to ON, but ffmpeg could not be found.")
		endif()
		set(CHIAKI_ENABLE_FFMPEG_DECODER OFF)
	endif()
endif()

if(CHIAKI_ENABLE_FFMPEG_DECODER)
	message(STATUS "FFMPEG Decoder enabled")
else()
	message(STATUS "FFMPEG Decoder disabled")
endif()

if(CHIAKI_ENABLE_PI_DECODER)
	find_package(ILClient)
	if(ILClient_FOUND)
		set(CHIAKI_ENABLE_PI_DECODER ON)
	else()
		if(NOT CHIAKI_ENABLE_PI_DECODER STREQUAL AUTO)
			message(FATAL_ERROR "
CHIAKI_ENABLE_PI_DECODER is set to ON, but its dependencies (ilclient source and libs) could not be resolved.
The Raspberry Pi Decoder is only supported on Raspberry Pi OS and requires libraspberrypi0 and libraspberrypi-doc.")
		endif()
		set(CHIAKI_ENABLE_PI_DECODER OFF)
	endif()
endif()

if(CHIAKI_ENABLE_PI_DECODER)
	message(STATUS "Pi Decoder enabled")
else()
	message(STATUS "Pi Decoder disabled")
endif()

if(CHIAKI_ENABLE_RUDP AND CHIAKI_LIB_JSONC_EXTERNAL_PROJECT)
	include(JsoncExternalProject)
endif()

if(CHIAKI_ENABLE_RUDP AND CHIAKI_LIB_MINIUPNPC_EXTERNAL_PROJECT)
	include(MiniupnpcExternalProject)
endif()

add_subdirectory(lib)

if((CLOUD_LAUNCHER_SPLIT_POC_TOOLS OR CLOUD_LAUNCHER_PRODUCTION_PLAYER) AND WIN32)
	set(CLOUD_LAUNCHER_GATEWAY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../cloud-launcher-chiaki-gateway")
	add_subdirectory("${CLOUD_LAUNCHER_GATEWAY_DIR}"
		"${CMAKE_CURRENT_BINARY_DIR}/cloud-launcher-chiaki-gateway" EXCLUDE_FROM_ALL)
endif()

if(CLOUD_LAUNCHER_SPLIT_POC_TOOLS AND WIN32)
	add_executable(CloudLauncherChiakiPair WIN32
		"${CLOUD_LAUNCHER_GATEWAY_DIR}/tools/pair_gui.cpp"
		"${CLOUD_LAUNCHER_GATEWAY_DIR}/tools/pairing_core.cpp"
		"${CLOUD_LAUNCHER_GATEWAY_DIR}/tools/pair_gui.rc")
	add_executable(CloudLauncherChiakiPairCli
		"${CLOUD_LAUNCHER_GATEWAY_DIR}/tools/pair_cli.cpp"
		"${CLOUD_LAUNCHER_GATEWAY_DIR}/tools/pairing_core.cpp")
	add_executable(CloudLauncherChiakiBroker
		"${CLOUD_LAUNCHER_GATEWAY_DIR}/tools/broker_main.cpp"
		"${CLOUD_LAUNCHER_GATEWAY_DIR}/tools/pairing_core.cpp")
	add_executable(CloudLauncherChiakiPocClient "${CLOUD_LAUNCHER_GATEWAY_DIR}/tools/poc_client_main.cpp")
	target_include_directories(CloudLauncherChiakiPair PRIVATE "${CLOUD_LAUNCHER_GATEWAY_DIR}/include")
	target_include_directories(CloudLauncherChiakiPairCli PRIVATE "${CLOUD_LAUNCHER_GATEWAY_DIR}/include")
	target_include_directories(CloudLauncherChiakiPairCli PRIVATE
		"${CLOUD_LAUNCHER_GATEWAY_DIR}/../chiaki-ng/switch/borealis/library/include/borealis/extern")
	target_include_directories(CloudLauncherChiakiBroker PRIVATE
		"${CLOUD_LAUNCHER_GATEWAY_DIR}/../chiaki-ng/switch/borealis/library/include/borealis/extern")
	target_compile_features(CloudLauncherChiakiPair PRIVATE cxx_std_20)
	target_compile_features(CloudLauncherChiakiPairCli PRIVATE cxx_std_20)
	target_compile_features(CloudLauncherChiakiBroker PRIVATE cxx_std_20)
	target_compile_features(CloudLauncherChiakiPocClient PRIVATE cxx_std_20)
	target_compile_definitions(CloudLauncherChiakiPair PRIVATE WIN32_LEAN_AND_MEAN NOMINMAX UNICODE _UNICODE)
	target_compile_definitions(CloudLauncherChiakiPairCli PRIVATE WIN32_LEAN_AND_MEAN NOMINMAX)
	target_compile_definitions(CloudLauncherChiakiBroker PRIVATE WIN32_LEAN_AND_MEAN NOMINMAX)
	target_compile_definitions(CloudLauncherChiakiPocClient PRIVATE WIN32_LEAN_AND_MEAN NOMINMAX)
	target_link_libraries(CloudLauncherChiakiPair PRIVATE chiaki-lib cloud_gateway_core shell32 crypt32)
	target_link_libraries(CloudLauncherChiakiPairCli PRIVATE chiaki-lib cloud_gateway_core crypt32)
	target_link_libraries(CloudLauncherChiakiBroker PRIVATE chiaki-lib cloud_gateway_core crypt32)
	target_include_directories(CloudLauncherChiakiPocClient PRIVATE
		"${CLOUD_LAUNCHER_GATEWAY_DIR}/../chiaki-ng/switch/borealis/library/include/borealis/extern")
	target_link_libraries(CloudLauncherChiakiPocClient PRIVATE chiaki-lib cloud_gateway_core)
	if(BUILD_TESTING)
		add_executable(CloudLauncherChiakiPairingCoreTests
			"${CLOUD_LAUNCHER_GATEWAY_DIR}/tests/pairing_core_tests.cpp"
			"${CLOUD_LAUNCHER_GATEWAY_DIR}/tools/pairing_core.cpp")
		target_include_directories(CloudLauncherChiakiPairingCoreTests PRIVATE
			"${CLOUD_LAUNCHER_GATEWAY_DIR}/include")
		target_compile_features(CloudLauncherChiakiPairingCoreTests PRIVATE cxx_std_20)
		target_compile_definitions(CloudLauncherChiakiPairingCoreTests PRIVATE
			WIN32_LEAN_AND_MEAN NOMINMAX)
		target_link_libraries(CloudLauncherChiakiPairingCoreTests PRIVATE
			chiaki-lib cloud_gateway_core crypt32)
		add_test(NAME cloud_gateway_pairing_core_tests
			COMMAND CloudLauncherChiakiPairingCoreTests)
	endif()
endif()

if(CHIAKI_ENABLE_CLI)
	add_subdirectory(cli)
endif()

if(CHIAKI_ENABLE_STEAMDECK_NATIVE)
	find_package(HIDAPI QUIET)
	find_package(PkgConfig REQUIRED)
	pkg_search_module(FFTW REQUIRED fftw3 IMPORTED_TARGET)
	if(HIDAPI_FOUND AND FFTW_FOUND)
		set(CHIAKI_ENABLE_STEAMDECK_NATIVE ON)
	else()
		if(NOT CHIAKI_ENABLE_STEAMDECK_NATIVE STREQUAL AUTO)
			if(NOT HIDAPI_FOUND AND NOT FFTW_FOUND)
				message(FATAL_ERROR "
				CHIAKI_ENABLE_STEAMDECK_NATIVE is set to ON, but its dependencies (HIDAPI & FFTW3) could not be resolved.")
			endif()
			if(NOT HIDAPI_FOUND)
				message(FATAL_ERROR "
				CHIAKI_ENABLE_STEAMDECK_NATIVE is set to ON, but its dependency (HIDAPI) could not be resolved.")
			endif()
			if(NOT FFTW_FOUND)
				message(FATAL_ERROR "
				CHIAKI_ENABLE_STEAMDECK_NATIVE is set to ON, but its dependency (FFTW3) could not be resolved.")
			endif()
		endif()
		set(CHIAKI_ENABLE_STEAMDECK_NATIVE OFF)
	endif()
	if(CHIAKI_ENABLE_STEAMDECK_NATIVE)
		add_subdirectory(steamdeck_native)
	endif()
endif()

if(CHIAKI_ENABLE_STEAMDECK_NATIVE)
	message(STATUS "Steamdeck native gyro and haptics enabled")
else()
	message(STATUS "Steamdeck native gyro and hatpics disabled")
endif()

if(CHIAKI_ENABLE_GUI)
	find_package(SDL2 MODULE REQUIRED)
endif()

if(CHIAKI_ENABLE_SETSU)
	if(CHIAKI_ENABLE_SETSU STREQUAL AUTO AND SDL2_FOUND AND (SDL2_VERSION_MINOR GREATER 0 OR SDL2_VERSION_PATCH GREATER_EQUAL 14))
		message(STATUS "SDL version ${SDL2_VERSION} is >= 2.0.14, disabling Setsu")
		set(CHIAKI_ENABLE_SETSU OFF)
	else()
		find_package(Udev QUIET)
		find_package(Evdev QUIET)
		if(Udev_FOUND AND Evdev_FOUND)
			set(CHIAKI_ENABLE_SETSU ON)
		else()
			if(NOT CHIAKI_ENABLE_SETSU STREQUAL AUTO)
				message(FATAL_ERROR "
	CHIAKI_ENABLE_SETSU is set to ON, but its dependencies (udev and evdev) could not be resolved.
	Keep in mind that setsu is only supported on Linux!")
			endif()
			set(CHIAKI_ENABLE_SETSU OFF)
		endif()
		if(CHIAKI_ENABLE_SETSU)
			add_subdirectory(setsu)
		endif()
	endif()
endif()

if(CHIAKI_ENABLE_SETSU)
	message(STATUS "Setsu enabled")
else()
	message(STATUS "Setsu disabled")
endif()

if(CHIAKI_ENABLE_GUI)
	add_subdirectory(gui)
endif()

if(CHIAKI_ENABLE_TESTS)
	enable_testing()
	add_subdirectory(test)
endif()

if(CHIAKI_ENABLE_ANDROID)
	add_subdirectory(android/app)
endif()

if(CHIAKI_ENABLE_BOREALIS)
	add_subdirectory(switch)
endif()
